parse.icl

   1 implementation module parse
   2
   3 import GenPrint
   4 import StdString
   5 import StdTuple
   6 import StdList
   7 from StdFunc import const, o
   8 import Data.Either
   9 import Data.Maybe
  10 import Data.Functor
  11 import Data.Tuple
  12 import Control.Monad
  13 import Control.Applicative
  14 import Data.Func
  15 import StdMisc
  16 from Data.List import intercalate, replicate, instance Functor []
  17 from Text import class Text(concat), instance Text String
  18
  19 import yard
  20 import lex
  21 import AST
  22
  23 parser :: [Token] -> ParserOutput
  24 parser ts = case runParser parseProgram ts of
  25         (Right ast, [(p, t):xs]) = Left $ PositionalError p.line p.col (
  26                 "Unable to parse from: " +++ printToString t)
  27         x = fst x
  28
  29 parseProgram :: Parser Token AST
  30 parseProgram = many parseLetDecl >>= \fds1->
  31                 some parseFunDecl >>= \fds2->
  32                 pure $ AST (fds1++fds2)
  33
  34 parseLetDecl :: Parser Token FunDecl
  35 parseLetDecl = peekPos >>= \p->
  36                 satTok LetToken >>|
  37                 parseFunType >>= \mt->
  38                 parseIdent >>= \f->
  39                 satTok AssignmentToken >>|
  40                 parseExpr >>= \e->
  41                 satTok SColonToken >>|
  42                 pure (FunDecl p f [] (Just mt) [] [ReturnStmt $ Just e])
  43
  44 parseFunDecl :: Parser Token FunDecl
  45 parseFunDecl = liftM6 FunDecl
  46     (peekPos)
  47     (parseIdent)
  48         (parseBBraces $ parseSepList CommaToken parseIdent)
  49         (optional (satTok DoubleColonToken *> parseFunType))
  50         (satTok CBraceOpenToken *> many parseVarDecl)
  51         (flatten <$> (many parseStmt <* satTok CBraceCloseToken))
  52
  53 parseStmt :: Parser Token [Stmt]
  54 parseStmt = (parseIfStmt <|> parseWhileStmt <|>
  55         parseSColon parseAssStmt <|> parseSColon parseReturnStmt <|>
  56         (parseSColon parseFunCall
  57                 >>= \(ident, args, fs)->pure $ FunStmt ident args fs))
  58         >>= \stmt->case stmt of
  59                 FunStmt "print" args fs = pure $ map (\a->FunStmt "print" [a] []) args
  60                 s = pure [s]
  61         where
  62                 parseSColon :: (Parser Token a) -> Parser Token a
  63                 parseSColon p = p <* satTok SColonToken
  64
  65                 parseReturnStmt :: Parser Token Stmt
  66                 parseReturnStmt =
  67                         satTok ReturnToken *> liftM ReturnStmt (optional parseExpr)
  68
  69                 parseAssStmt :: Parser Token Stmt
  70                 parseAssStmt =
  71                         AssStmt <$> (parseVarDef <* satTok AssignmentToken) <*> parseExpr
  72
  73                 parseIfStmt :: Parser Token Stmt
  74                 parseIfStmt = liftM3 IfStmt
  75             (satTok IfToken *> parseBBraces parseExpr)
  76             (parseBlock <|> parseOneLine)
  77             (liftM (fromMaybe [])
  78                 (optional (satTok ElseToken *> (parseBlock<|> parseOneLine))))
  79
  80                 parseWhileStmt :: Parser Token Stmt
  81                 parseWhileStmt = satTok WhileToken *> (WhileStmt <$>
  82                         (parseBBraces parseExpr) <*> (parseBlock <|> parseOneLine))
  83
  84                 parseBlock :: Parser Token [Stmt]
  85                 parseBlock = parseBCBraces (flatten <$> many parseStmt)
  86
  87                 parseOneLine :: Parser Token [Stmt]
  88                 parseOneLine = parseStmt
  89
  90 parseFunType :: Parser Token Type
  91 parseFunType = parseFT >>= \t -> case t of
  92         t1 ->> t2   = pure t
  93         simpleT     = pure $ FuncType simpleT
  94         where
  95         parseFT :: Parser Token Type
  96                 parseFT = (liftM2 (->>) (parseSF <* satTok ArrowToken) (parseFT)) <|>
  97                         parseSF
  98                 parseSF :: Parser Token Type
  99                 parseSF = parseBBraces parseFT <|> parseType
 100
 101 parseVarDecl :: Parser Token VarDecl
 102 parseVarDecl = liftM4 VarDecl
 103     peekPos
 104         ((parseType >>= \t->pure $ Just t)<|> trans1 VarToken Nothing)
 105         (parseIdent <* satTok AssignmentToken)
 106         (parseExpr <* satTok SColonToken)
 107
 108 parseType :: Parser Token Type
 109 parseType =
 110         trans1 IntTypeToken IntType <|>
 111         trans1 CharTypeToken CharType <|>
 112         trans1 BoolTypeToken BoolType <|>
 113     trans1 VoidToken VoidType <|>
 114         (ListType <$> (parseBSqBraces parseType)) <|>
 115         (TupleType <$> (parseTuple parseType)) <|>
 116         (IdType <$> parseIdent)
 117
 118 parseExpr :: Parser Token Expr
 119 parseExpr = parseValueExpr <|> parseLambda
 120
 121 parseValueExpr :: Parser Token Expr
 122 parseValueExpr = //Operators in order of binding strength
 123         parseOpR (trans1 ColonToken BiCons) $
 124         parseOpR (trans1 PipesToken BiOr) $
 125         parseOpR (trans1 AmpersandsToken BiAnd) $
 126         parseOpR (trans1 EqualsToken BiEquals <|>
 127                         trans1 LesserToken BiLesser <|>
 128                         trans1 BiggerToken BiGreater <|>
 129                         trans1 LesserEqToken BiLesserEq <|>
 130                         trans1 GreaterEqToken BiGreaterEq <|>
 131                         trans1 NotEqualToken BiUnEqual) $
 132         parseOpL (trans1 PlusToken BiPlus <|>
 133                         trans1 DashToken BiMinus) $
 134         parseOpL (trans1 StarToken BiTimes <|>
 135                         trans1 SlashToken BiDivide <|>
 136                         trans1 PercentToken BiMod) $ parseBasicExpr
 137         where
 138                 parseOpR :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 139                 parseOpR ops prev = peekPos >>= \pos-> prev >>= \e1->optional (
 140                                 ops >>= \op->parseOpR ops prev >>= \e->pure (op, e)
 141                         ) >>= \moe->pure $ maybe e1 (\(op,e2)->Op2Expr pos e1 op e2) moe
 142
 143                 parseOpL :: (Parser Token Op2) (Parser Token Expr) -> Parser Token Expr
 144                 parseOpL ops prev = peekPos >>= \pos-> prev >>= \e1->many (
 145                                 ops >>= \op->prev >>= \e->pure (op, e))
 146                         >>= \moe->foldM (\e->(\(op,e2)->pure $ Op2Expr pos e op e2)) e1 moe
 147
 148                 parseBasicExpr :: Parser Token Expr
 149                 parseBasicExpr = peekPos >>= \pos ->
 150                         (trans2 (StringToken []) (\(StringToken cs)->makeStrExpr pos cs)) <|>
 151                         (TupleExpr pos <$> (parseTuple parseExpr)) <|>
 152                         parseBBraces parseExpr <|>
 153             parseListLiteral <|>
 154                         trans1 EmptyListToken (EmptyListExpr pos) <|>
 155                         trans1 TrueToken (BoolExpr pos True) <|>
 156                         trans1 FalseToken (BoolExpr pos False) <|>
 157                         trans2 (NumberToken zero) (\(NumberToken i)->IntExpr pos i) <|>
 158                         trans2 (CharToken zero) (\(CharToken c)->CharExpr pos c) <|>
 159                         (Op1Expr pos <$> parseOp1 <*> parseExpr) <|>
 160                         (parseFunCall >>= \(ident, args, fs)->
 161                                 pure $ FunExpr pos ident args fs) <|>
 162                         (VarExpr pos <$> parseVarDef)
 163
 164         parseListLiteral :: Parser Token Expr
 165         parseListLiteral = peekPos >>= \p->
 166             satTok SquareOpenToken >>|
 167             many (parseExpr <* satTok CommaToken) >>= \es->
 168             parseExpr >>= \e->
 169             foldM   (\res e-> pure $ Op2Expr p e BiCons res)
 170                     (EmptyListExpr p)
 171                     [e : reverse es] >>= \res->
 172             satTok SquareCloseToken >>|
 173             pure res
 174
 175 parseLambda :: Parser Token Expr
 176 parseLambda = LambdaExpr <$> peekPos
 177                         <*> (satTok BackslashToken *> many parseIdent)
 178                         <*> (satTok ArrowToken *> parseExpr)
 179
 180 makeStrExpr :: Pos [Char] -> Expr
 181 makeStrExpr p [] = EmptyListExpr p
 182 makeStrExpr p [x:xs] = Op2Expr p (CharExpr zero x) BiCons (makeStrExpr p xs)
 183
 184 parseFunCall :: Parser Token (String, [Expr], [FieldSelector])
 185 parseFunCall = liftM3 (\x y z->(x, y, z))
 186         parseIdent
 187         (parseBBraces $ parseSepList CommaToken parseExpr)
 188         parseFieldSelectors
 189
 190 parseVarDef :: Parser Token VarDef
 191 parseVarDef = liftM2 VarDef parseIdent parseFieldSelectors
 192
 193 parseFieldSelectors :: Parser Token [FieldSelector]
 194 parseFieldSelectors = many (satTok DotToken *>
 195         parseIdent >>= \i->case i of
 196                 "hd" = pure FieldHd
 197                 "tl" = pure FieldTl
 198                 "fst" = pure FieldFst
 199                 "snd" = pure FieldSnd
 200                 _ = empty)
 201
 202 parseOp1 :: Parser Token Op1
 203 parseOp1 = trans1 DashToken UnMinus <|> trans1 ExclamationToken UnNegation
 204
 205 parseBBraces :: (Parser Token a) -> Parser Token a
 206 parseBBraces p = satTok BraceOpenToken *> p <* satTok BraceCloseToken
 207
 208 parseBCBraces :: (Parser Token a) -> Parser Token a
 209 parseBCBraces p = satTok CBraceOpenToken *> p <* satTok CBraceCloseToken
 210
 211 parseBSqBraces :: (Parser Token a) -> Parser Token a
 212 parseBSqBraces p = satTok SquareOpenToken *> p <* satTok SquareCloseToken
 213
 214 parseTuple :: (Parser Token a) -> Parser Token (a, a)
 215 parseTuple p = satTok BraceOpenToken *>
 216         (liftM2 tuple (p <* satTok CommaToken) p)
 217         <* satTok BraceCloseToken
 218
 219 trans :: TokenValue (TokenValue -> a) -> Parser Token (Pos, a)
 220 trans t f = (\(pos,token)->(pos, f token)) <$> satTok t
 221
 222 trans2 :: TokenValue (TokenValue -> a) -> Parser Token a
 223 trans2 t f = snd <$> trans t f
 224
 225 trans1 :: TokenValue a -> Parser Token a
 226 trans1 t r = trans2 t $ const r
 227
 228 peekPos :: Parser Token Pos
 229 peekPos = fst <$> peek
 230
 231 derive gPrint TokenValue
 232 derive gEq TokenValue
 233 satTok :: TokenValue -> Parser Token Token
 234 satTok t = top >>= \tok=:({line,col},token) -> if (tokEq t token)
 235         (pure tok) (fail <?> PositionalError line col
 236                 ("ParseError: Unexpected token: " +++ printToString token
 237             +++ "\nExpected: " +++ printToString t))
 238
 239 tokEq (IdentToken _) (IdentToken _) = True
 240 tokEq (NumberToken _) (NumberToken _) = True
 241 tokEq (CharToken _) (CharToken _) = True
 242 tokEq (StringToken _) (StringToken _) = True
 243 tokEq x y = gEq {|*|} x y
 244
 245 parseSepList :: TokenValue (Parser Token a) -> Parser Token [a]
 246 parseSepList sep p = pSL` sep p <|> pure []
 247         where
 248                 pSL` sep p = (p <* satTok sep >>= \v1->parseSepList sep p >>= \vs->pure [v1:vs]) <|> (p >>= \v->pure [v])
 249
 250 parseIdent :: Parser Token String
 251 parseIdent = trans2 (IdentToken "") (\(IdentToken e)->toString e)
 252
 253 //liftM only goes to liftM5
 254 liftM6 f m1 m2 m3 m4 m5 m6 = f <$> m1 <*> m2 <*> m3 <*> m4 <*> m5 <*> m6