IRC.icl

   1 implementation module IRC
   2
   3 import StdList, StdTuple, StdOverloaded, StdFunc, StdString, StdChar, StdBool
   4 import GenPrint
   5 import Data.Maybe
   6 import Data.Either
   7 import _SystemArray
   8
   9 import Text.Parsers.Simple.Core
  10 import Text.Parsers.Simple.Chars
  11 import Data.Tuple
  12 import Control.Monad
  13 import Control.Applicative
  14
  15 from Data.Functor import <$>
  16 from Data.Func import $
  17 from Text import class Text(trim,rtrim,split,indexOf,concat), instance Text String
  18 import qualified Text
  19 from StdMisc import undef
  20
  21 jon :== 'Text'.join
  22
  23 derive gPrint IRCCommand, IRCReplies, IRCErrors, (,), Maybe, (), Either, IRCMessage, IRCUser, IRCNumReply
  24
  25 Start = jon "\n" $ map printToString
  26         [ parseIRCMessage ":clooglebot!~cloogle@dhcp-077-249-221-037.chello.nl QUIT\r\n"
  27         , parseIRCMessage ":clooglebot!~cloogle QUIT\r\n"
  28         , parseIRCMessage ":frobnicator!~frobnicat@92.110.128.124 QUIT\r\n"
  29         , parseIRCMessage ":frobnicator!~frobnicat@92.110.128.124 AWAY test\r\n"
  30         , parseIRCMessage ":frobnicator!~frobnicat@92.110.128.124 AWAY :test with spaces\r\n"
  31         , parseIRCMessage ":cherryh.freenode.net NOTICE * :*** Found your hostname\r\n"
  32         , parseIRCMessage ":cherryh.freenode.net QUIT :hoi hoi\r\n"
  33         , parseIRCMessage ":cherryh.freenode.net ISON a b c d e f :g h\r\n"
  34         ]
  35
  36 (<+) infixr 5 :: a b -> String | toString a & toString b
  37 (<+) a b = toString a +++ toString b
  38
  39 parseIRCMessage :: String -> Either [Error] IRCMessage
  40 parseIRCMessage s = case runParser parsePrefix (fromString s) of
  41         ([(prefix, rest):_], _)
  42                 = case parse parseReply rest of
  43                         Left e = case parseCmd rest of
  44                                 Left e2 = Left $ e2 ++ e
  45                                 Right cmd = Right {IRCMessage | irc_prefix=prefix, irc_command=Right cmd}
  46                         Right repl = Right {IRCMessage | irc_prefix=prefix, irc_command=Left repl}
  47         (_, es) = Left ["couldn't parse prefix":es]
  48
  49 parsePrefix :: Parser Char (Maybe (Either IRCUser String))
  50 parsePrefix = optional (pToken ':' >>| parseEither parseUser parseHost) <* pToken ' '
  51
  52 pOne [] = (Left ["Expected an argument"], [])
  53 pOne [a:as] = (Right a, as)
  54
  55 generic gIRCParse a :: [String] -> (Either [Error] a, [String])
  56 gIRCParse{|UNIT|} a = (Right UNIT, a)
  57 gIRCParse{|String|} as = pOne as
  58 gIRCParse{|Int|} as = appFst (fmap toInt) $ pOne as
  59 gIRCParse{|EITHER|} lp rp as = case lp as of
  60         (Right a, rest) = (Right $ LEFT a, rest)
  61         (Left e1, _) = case rp as of
  62                 (Right a, rest) = (Right $ RIGHT a, rest)
  63                 (Left e2, _) = (Left $ e1 ++ e2, [])
  64 gIRCParse{|OBJECT|} p as = appFst (fmap OBJECT) $ p as
  65 gIRCParse{|CONS of d|} p [] = (Left ["Expected a cmd constructor: " +++ d.gcd_name], [])
  66 gIRCParse{|CONS of d|} p [a:as]
  67 | a <> d.gcd_name = (Left ["Wrong constructor. expected: " +++ d.gcd_name +++ ", got: " +++ a], [])
  68 = case p as of
  69         (Right a, rest) = (Right $ CONS a, rest)
  70         (Left e, _) = (Left e, [])
  71 gIRCParse{|PAIR|} pl pr as = case pl as of
  72         (Right a1, rest) = case pr rest of
  73                 (Right a2, rest) = (Right $ PAIR a1 a2, rest)
  74                 (Left e, _) = (Left e, [])
  75         (Left e, _) = (Left e, [])
  76 gIRCParse{|[]|} pl as = case pl as of
  77                 (Right e, rest) = case gIRCParse{|*->*|} pl rest of
  78                         (Right es, rest) = (Right [e:es], rest)
  79                         (Left e, _) = (Left e, [])
  80                 (Left e, _) = (Right [], as)
  81 gIRCParse{|Maybe|} pm as
  82         = appFst (either (const $ Right Nothing) $ Right o Just) $ pm as
  83
  84 derive gIRCParse (,), (,,), IRCCommand
  85
  86 parseCmd :: [Char] -> Either [Error] IRCCommand
  87 parseCmd cs = fst $ gIRCParse{|*|} $ argfun $ split " " $ toString cs
  88         where
  89                 argfun :: [String] -> [String]
  90                 argfun [] = []
  91                 argfun [x:xs]
  92                 # x = trim x
  93                 | x.[0] == ':' = [jon " " $ [x:map rtrim xs]]
  94                 | otherwise = [x:argfun xs]
  95
  96 parseReply :: Parser Char IRCNumReply
  97 parseReply = (toString <$> pSome pDigit)
  98         >>= \rep->pMiddle
  99         >>= \recipient->spaceParser >>| (toString <$> pSome (pNoneOf illegal))
 100         >>= \msg->pure {IRCNumReply|irc_reply=fs rep,irc_recipient=recipient,irc_message=msg}
 101         where
 102                 fs :: String -> IRCReplies
 103                 fs s = fromInt $ toInt s
 104 //
 105 spaceParser :: Parser Char [Char]
 106 spaceParser = pMany $ pToken ' '
 107 //
 108 //parseServer :: Parser Char String
 109 //parseServer = pFail
 110 //
 111 parseEither :: (Parser a b) (Parser a c) -> Parser a (Either b c)
 112 parseEither p q = Left <$> p <|> Right <$> q
 113
 114 parseUser :: Parser Char IRCUser
 115 parseUser = parseNick
 116                 >>= \nick->optional (pToken '!' >>| parseUsr)
 117                 >>= \muser->optional (pToken '@' >>| parseHost)
 118                 >>= \mhost->pure {IRCUser | irc_nick=nick, irc_user=muser, irc_host=mhost}
 119
 120 parseUsr :: Parser Char String
 121 parseUsr = toString <$> pSome (pNoneOf [' ', '@':illegal])
 122
 123 parseNick :: Parser Char String
 124 parseNick = pAlpha >>= \c->pMany (pAlpha <|> pDigit <|> pSpecial)
 125         >>= \cs->pure (toString [c:cs])
 126
 127 pSpecial :: Parser Char Char
 128 pSpecial = pOneOf ['-', '[', ']', '\\', '\`', '^', '{', '}']
 129
 130 parseHost :: Parser Char String
 131 parseHost = jon "." <$> pSepBy parseName (pToken '.')
 132         where
 133                 parseName :: Parser Char String
 134                 parseName = toString <$> pSome (pAlpha <|> pDigit <|> pOneOf ['-'])
 135
 136 instance toString IRCNumReply where
 137         toString m = toInt m.irc_reply <+ " " <+ m.irc_recipient <+ " " <+ formatMSG m.irc_message
 138 instance toString IRCMessage where
 139         toString m = maybe "" (\s->either ((<+) ":") id s <+ " ") m.irc_prefix
 140                 <+ either toString toString m.irc_command
 141
 142 instance toString IRCUser where
 143         toString m = m.irc_nick <+ maybe "" ((<+) "!") m.irc_user
 144                 <+ maybe "" ((<+) "@") m.irc_host
 145
 146 pMiddle :: Parser Char String
 147 pMiddle = fmap toString $
 148         spaceParser >>| liftM2 (\x xs->[x:xs]) (pSatisfy (not o ((==)':')) (pMany $ pNoneOf [' ':illegal]))
 149
 150 pNoneOf :: [a] -> Parser a a | Eq a
 151 pNoneOf l = pSatisfy (not o flip isMember l)
 152
 153 illegal :: [Char]
 154 illegal = ['\x00','\r','\n']
 155
 156 instance toString IRCCommand where
 157         toString r = jon " " (gIRCPrint{|*|} r) +++ "\r\n"
 158
 159 formatMSG :: String -> String
 160 formatMSG s = if (indexOf " " s > 0 || indexOf " " s > 0) (":" +++ s) s
 161
 162 instance toString IRCReplies where toString r = printToString r
 163 instance toString IRCErrors where toString r = printToString r
 164
 165 instance fromInt IRCReplies where
 166         fromInt r = case r of
 167                 1 = RPL_WELCOME; 2 = RPL_YOURHOST;
 168                 3 = RPL_CREATED; 4 = RPL_MYINFO;
 169                 5 = RPL_BOUNCE; 200 = RPL_TRACELINK;
 170                 201 = RPL_TRACECONNECTING; 202 = RPL_TRACEHANDSHAKE;
 171                 203 = RPL_TRACEUNKNOWN; 204 = RPL_TRACEOPERATOR;
 172                 205 = RPL_TRACEUSER; 206 = RPL_TRACESERVER;
 173                 207 = RPL_TRACESERVICE; 208 = RPL_TRACENEWTYPE;
 174                 209 = RPL_TRACECLASS; 210 = RPL_TRACERECONNECT;
 175                 211 = RPL_STATSLINKINFO; 212 = RPL_STATSCOMMANDS;
 176                 219 = RPL_ENDOFSTATS; 221 = RPL_UMODEIS;
 177                 234 = RPL_SERVLIST; 235 = RPL_SERVLISTEND;
 178                 242 = RPL_STATSUPTIME; 243 = RPL_STATSOLINE;
 179                 251 = RPL_LUSERCLIENT; 252 = RPL_LUSEROP;
 180                 253 = RPL_LUSERUNKNOWN; 254 = RPL_LUSERCHANNELS;
 181                 255 = RPL_LUSERME; 256 = RPL_ADMINME;
 182                 257 = RPL_ADMINLOC1; 258 = RPL_ADMINLOC2;
 183                 259 = RPL_ADMINEMAIL; 261 = RPL_TRACELOG;
 184                 262 = RPL_TRACEEND; 263 = RPL_TRYAGAIN;
 185                 301 = RPL_AWAY; 302 = RPL_USERHOST;
 186                 303 = RPL_ISON; 304 = RPL_UNAWAY;
 187                 305 = RPL_NOWAWAY; 311 = RPL_WHOISUSER;
 188                 312 = RPL_WHOISSERVER; 313 = RPL_WHOISOPERATOR;
 189                 314 = RPL_WHOWASUSER; 315 = RPL_ENDOFWHO;
 190                 317 = RPL_WHOISIDLE; 318 = RPL_ENDOFWHOIS;
 191                 319 = RPL_WHOISCHANNELS; 321 = RPL_LISTSTART;
 192                 322 = RPL_LIST; 323 = RPL_LISTEND;
 193                 324 = RPL_CHANNELMODEIS; 325 = RPL_UNIQOPIS;
 194                 331 = RPL_NOTOPIC; 332 = RPL_TOPIC;
 195                 341 = RPL_INVITING; 342 = RPL_SUMMONING;
 196                 346 = RPL_INVITELIST; 347 = RPL_ENDOFINVITELIST;
 197                 348 = RPL_EXCEPTLIST; 349 = RPL_ENDOFEXCEPTLIST;
 198                 351 = RPL_VERSION; 352 = RPL_WHOREPLY;
 199                 353 = RPL_NAMREPLY; 364 = RPL_LINKS;
 200                 365 = RPL_ENDOFLINKS; 366 = RPL_ENDOFNAMES;
 201                 367 = RPL_BANLIST; 368 = RPL_ENDOFBANLIST;
 202                 369 = RPL_ENDOFWHOWAS; 371 = RPL_INFO;
 203                 372 = RPL_MOTD; 374 = RPL_ENDOFINFO;
 204                 375 = RPL_MOTDSTART; 376 = RPL_ENDOFMOTD;
 205                 381 = RPL_YOUREOPER; 382 = RPL_REHASHING;
 206                 383 = RPL_YOURESERVICE; 391 = RPL_TIME;
 207                 392 = RPL_USERSSTART; 393 = RPL_USERS;
 208                 394 = RPL_ENDOFUSERS; 395 = RPL_NOUSERS;
 209                 _ = undef
 210
 211 instance toInt IRCReplies where
 212         toInt r = case r of
 213                 RPL_WELCOME = 1; RPL_YOURHOST = 2;
 214                 RPL_CREATED = 3; RPL_MYINFO = 4;
 215                 RPL_BOUNCE = 5; RPL_TRACELINK = 200;
 216                 RPL_TRACECONNECTING = 201; RPL_TRACEHANDSHAKE = 202;
 217                 RPL_TRACEUNKNOWN = 203; RPL_TRACEOPERATOR = 204;
 218                 RPL_TRACEUSER = 205; RPL_TRACESERVER = 206;
 219                 RPL_TRACESERVICE = 207; RPL_TRACENEWTYPE = 208;
 220                 RPL_TRACECLASS = 209; RPL_TRACERECONNECT = 210;
 221                 RPL_STATSLINKINFO = 211; RPL_STATSCOMMANDS = 212;
 222                 RPL_ENDOFSTATS = 219; RPL_UMODEIS = 221;
 223                 RPL_SERVLIST = 234; RPL_SERVLISTEND = 234;
 224                 RPL_STATSUPTIME = 242; RPL_STATSOLINE = 243;
 225                 RPL_LUSERCLIENT = 251; RPL_LUSEROP = 252;
 226                 RPL_LUSERUNKNOWN = 253; RPL_LUSERCHANNELS = 254;
 227                 RPL_LUSERME = 255; RPL_ADMINME = 256;
 228                 RPL_ADMINLOC1 = 257; RPL_ADMINLOC2 = 258;
 229                 RPL_ADMINEMAIL = 259; RPL_TRACELOG = 261;
 230                 RPL_TRACEEND = 262; RPL_TRYAGAIN = 263;
 231                 RPL_AWAY = 301; RPL_USERHOST = 302;
 232                 RPL_ISON = 303; RPL_UNAWAY = 304;
 233                 RPL_NOWAWAY = 305; RPL_WHOISUSER = 311;
 234                 RPL_WHOISSERVER = 312; RPL_WHOISOPERATOR = 313;
 235                 RPL_WHOWASUSER = 314; RPL_ENDOFWHO = 315;
 236                 RPL_WHOISIDLE = 317; RPL_ENDOFWHOIS = 318;
 237                 RPL_WHOISCHANNELS = 319; RPL_LISTSTART = 321;
 238                 RPL_LIST = 322; RPL_LISTEND = 323;
 239                 RPL_CHANNELMODEIS = 324; RPL_UNIQOPIS = 325;
 240                 RPL_NOTOPIC = 331; RPL_TOPIC = 332;
 241                 RPL_INVITING = 341; RPL_SUMMONING = 342;
 242                 RPL_INVITELIST = 346; RPL_ENDOFINVITELIST = 347;
 243                 RPL_EXCEPTLIST = 348; RPL_ENDOFEXCEPTLIST = 349;
 244                 RPL_VERSION = 351; RPL_WHOREPLY = 352;
 245                 RPL_NAMREPLY = 353; RPL_LINKS = 364;
 246                 RPL_ENDOFLINKS = 365; RPL_ENDOFNAMES = 366;
 247                 RPL_BANLIST = 367; RPL_ENDOFBANLIST = 367;
 248                 RPL_ENDOFWHOWAS = 369; RPL_INFO = 371;
 249                 RPL_MOTD = 372; RPL_ENDOFINFO = 374;
 250                 RPL_MOTDSTART = 375; RPL_ENDOFMOTD = 376;
 251                 RPL_YOUREOPER = 381; RPL_REHASHING = 382;
 252                 RPL_YOURESERVICE = 383; RPL_TIME = 391;
 253                 RPL_USERSSTART = 392; RPL_USERS = 393;
 254                 RPL_ENDOFUSERS = 394; RPL_NOUSERS = 395;
 255
 256 instance fromInt IRCErrors where
 257         fromInt r = case r of
 258                 401 = ERR_NOSUCHNICK; 402 = ERR_NOSUCHSERVER;
 259                 403 = ERR_NOSUCHCHANNEL; 404 = ERR_CANNOTSENDTOCHAN;
 260                 405 = ERR_TOOMANYCHANNELS; 406 = ERR_WASNOSUCHNICK;
 261                 407 = ERR_TOOMANYTARGETS; 408 = ERR_NOSUCHSERVICE;
 262                 409 = ERR_NOORIGIN; 411 = ERR_NORECIPIENT;
 263                 412 = ERR_NOTEXTTOSEND; 413 = ERR_NOTOPLEVEL;
 264                 414 = ERR_WILDTOPLEVEL; 415 = ERR_BADMASK;
 265                 421 = ERR_UNKNOWNCOMMAND; 422 = ERR_NOMOTD;
 266                 423 = ERR_NOADMININFO; 424 = ERR_FILEERROR;
 267                 431 = ERR_NONICKNAMEGIVEN; 432 = ERR_ERRONEUSNICKNAME;
 268                 433 = ERR_NICKNAMEINUSE; 436 = ERR_NICKCOLLISION;
 269                 437 = ERR_UNAVAILRESOURCE; 441 = ERR_USERNOTINCHANNEL;
 270                 442 = ERR_NOTONCHANNEL; 443 = ERR_USERONCHANNEL;
 271                 444 = ERR_NOLOGIN; 445 = ERR_SUMMONDISABLED;
 272                 446 = ERR_USERSDISABLED; 451 = ERR_NOTREGISTERED;
 273                 461 = ERR_NEEDMOREPARAMS; 462 = ERR_ALREADYREGISTRED;
 274                 463 = ERR_NOPERMFORHOST; 464 = ERR_PASSWDMISMATCH;
 275                 465 = ERR_YOUREBANNEDCREEP; 466 = ERR_YOUWILLBEBANNED;
 276                 467 = ERR_KEYSET; 471 = ERR_CHANNELISFULL;
 277                 472 = ERR_UNKNOWNMODE; 473 = ERR_INVITEONLYCHAN;
 278                 474 = ERR_BANNEDFROMCHAN; 475 = ERR_BADCHANNELKEY;
 279                 476 = ERR_BADCHANMASK; 477 = ERR_NOCHANMODES;
 280                 478 = ERR_BANLISTFULL; 481 = ERR_NOPRIVILEGES;
 281                 482 = ERR_CHANOPRIVSNEEDED; 483 = ERR_CANTKILLSERVER;
 282                 484 = ERR_RESTRICTED; 485 = ERR_UNIQOPPRIVSNEEDED;
 283                 491 = ERR_NOOPERHOST; 501 = ERR_UMODEUNKNOWNFLAG;
 284                 502 = ERR_USERSDONTMATCH;
 285
 286 instance toInt IRCErrors where
 287         toInt r = case r of
 288                 ERR_NOSUCHNICK = 401; ERR_NOSUCHSERVER = 402;
 289                 ERR_NOSUCHCHANNEL = 403; ERR_CANNOTSENDTOCHAN = 404;
 290                 ERR_TOOMANYCHANNELS = 405; ERR_WASNOSUCHNICK = 406;
 291                 ERR_TOOMANYTARGETS = 407; ERR_NOSUCHSERVICE = 408;
 292                 ERR_NOORIGIN = 409; ERR_NORECIPIENT = 411;
 293                 ERR_NOTEXTTOSEND = 412; ERR_NOTOPLEVEL = 413;
 294                 ERR_WILDTOPLEVEL = 414; ERR_BADMASK = 415;
 295                 ERR_UNKNOWNCOMMAND = 421; ERR_NOMOTD = 422;
 296                 ERR_NOADMININFO = 423; ERR_FILEERROR = 424;
 297                 ERR_NONICKNAMEGIVEN = 431; ERR_ERRONEUSNICKNAME = 432;
 298                 ERR_NICKNAMEINUSE = 433; ERR_NICKCOLLISION = 436;
 299                 ERR_UNAVAILRESOURCE = 437; ERR_USERNOTINCHANNEL = 441;
 300                 ERR_NOTONCHANNEL = 442; ERR_USERONCHANNEL = 443;
 301                 ERR_NOLOGIN = 444; ERR_SUMMONDISABLED = 445;
 302                 ERR_USERSDISABLED = 446; ERR_NOTREGISTERED = 451;
 303                 ERR_NEEDMOREPARAMS = 461; ERR_ALREADYREGISTRED = 462;
 304                 ERR_NOPERMFORHOST = 463; ERR_PASSWDMISMATCH = 464;
 305                 ERR_YOUREBANNEDCREEP = 465; ERR_YOUWILLBEBANNED = 466;
 306                 ERR_KEYSET = 467; ERR_CHANNELISFULL = 471;
 307                 ERR_UNKNOWNMODE = 472; ERR_INVITEONLYCHAN = 473;
 308                 ERR_BANNEDFROMCHAN = 474; ERR_BADCHANNELKEY = 475;
 309                 ERR_BADCHANMASK = 476; ERR_NOCHANMODES = 477;
 310                 ERR_BANLISTFULL = 478; ERR_NOPRIVILEGES = 481;
 311                 ERR_CHANOPRIVSNEEDED = 482; ERR_CANTKILLSERVER = 483;
 312                 ERR_RESTRICTED = 484; ERR_UNIQOPPRIVSNEEDED = 485;
 313                 ERR_NOOPERHOST = 491; ERR_UMODEUNKNOWNFLAG = 501;
 314                 ERR_USERSDONTMATCH = 502;